将这些脚本复制到存储 U 盘的根目录。 请参考本页以便理解脚本中的内容。

示例脚本 ZIP 下载内容包含以下所有脚本：

映像部署脚本

以下脚本使用 WIM 或 FFU 映像文件设置 Windows 设备，然后提供用于配置一键重置功能的选项。

部署脚本由以下文件构成：

ApplyImage.bat

ApplyRecovery.bat

CreatePartitions-BIOS.txt

CreatePartitions-BIOS-FFU.txt

CreatePartitions-UEFI.txt

CreatePartitions-UEFI-FFU.txt

HideRecoveryPartitions-BIOS.txt

HideRecoveryPartitions-UEFI.txt

CreateRecoveryPartitions-BIOS.txt

CreateRecoveryPartitions-UEFI.txt

ApplyImage.bat

使用此脚本可将 Windows 映像应用于新设备。

注意：如果复制并粘贴以下内容来创建 .bat 文件，则在检测固件时可能会出错。 要使固件检测成功，请确保以 for /f "tokens=2* delims= " %%A 开头的行包含一个制表符，并且该制表符后面的 delims= 与 " %%A 之间有一个空格。

@echo Apply-Image.bat

@echo Run from the reference device in the WinPE environment.

@echo.

@echo This script erases the primary hard drive and applies a new image.

@echo.

@echo Make sure that this script is run from the folder that contains the

@echo supporting scripts

@echo.

@echo UPDATE (November 2017)

@echo * Added support for FFU deployments.

@echo.

@echo UPDATE (JULY 2016):

@echo * This script stops just after applying the image.

@echo This gives you an opportunity to add siloed provisioning packages (SPPs)

@echo so that you can include them in your recovery tools.

@echo.

@echo After the script is complete, use apply-recovery.bat to finish

@echo setting up the recovery tools.

@echo.

@echo * This script creates a now includes support for the /EA variables for quicker

@echo image capture and recovery.

@echo.

@echo * This script now includes support for the /EA variables for quicker

@echo image capture and recovery.

@echo.

@echo * This script now checks to see if you're booted into Windows PE.

@echo.

@if not exist X:\Windows\System32 echo ERROR: This script is built to run in Windows PE.

@if not exist X:\Windows\System32 goto END

@if %1.==. echo ERROR: To run this script, add a path to a Windows image file.

@if %1.==. echo Example: ApplyImage D:\WindowsWithFrench.wim

@if %1.==. goto END

@echo *********************************************************************

@echo == Setting high-performance power scheme to speed deployment ==

@call powercfg /s 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c

@echo *********************************************************************

@echo Checking to see the type of image being deployed

@if "%~x1" == ".wim" (GOTO WIM)

@if "%~x1" == ".ffu" (GOTO FFU)

@echo *********************************************************************

@if not "%~x1" == ".ffu". if not "%~x1" == ".wim" echo Please use this script with a WIM or FFU image.

@if not "%~x1" == ".ffu". if not "%~x1" == ".wim" GOTO END

:WIM

@echo Starting WIM Deployment

@echo *********************************************************************

@echo Checking to see if the PC is booted in BIOS or UEFI mode.

wpeutil UpdateBootInfo

for /f "tokens=2* delims= " %%A in ('reg query HKLM\System\CurrentControlSet\Control /v PEFirmwareType') DO SET Firmware=%%B

@echo Note: delims is a TAB followed by a space.

@if x%Firmware%==x echo ERROR: Can't figure out which firmware we're on.

@if x%Firmware%==x echo Common fix: In the command above:

@if x%Firmware%==x echo for /f "tokens=2* delims= "

@if x%Firmware%==x echo ...replace the spaces with a TAB character followed by a space.

@if x%Firmware%==x goto END

@if %Firmware%==0x1 echo The PC is booted in BIOS mode.

@if %Firmware%==0x2 echo The PC is booted in UEFI mode.

@echo *********************************************************************

@echo Do you want to create a Recovery partition?

@echo (If you're going to be working with FFUs, and need

@echo to expand the Windows partition after applying the FFU, type N).

@SET /P RECOVERY=(Y or N):

@if %RECOVERY%.==y. set RECOVERY=Y

@echo Formatting the primary disk...

@if %Firmware%==0x1 echo ...using BIOS (MBR) format and partitions.

@if %Firmware%==0x2 echo ...using UEFI (GPT) format and partitions.

@echo CAUTION: All the data on the disk will be DELETED.

@SET /P READY=Erase all data and continue? (Y or N):

@if %READY%.==y. set READY=Y

@if not %READY%.==Y. goto END

@if %Firmware%.==0x1. if %RECOVERY%.==Y. diskpart /s CreatePartitions-BIOS.txt

@if %Firmware%.==0x1. if not %RECOVERY%.==Y. diskpart /s CreatePartitions-BIOS-FFU.txt

@if %Firmware%.==0x2. if %RECOVERY%.==Y. diskpart /s CreatePartitions-UEFI.txt

@if %Firmware%.==0x2. if not %RECOVERY%.==Y. diskpart /s CreatePartitions-UEFI-FFU.txt

@echo *********************************************************************

@echo == Apply the image to the Windows partition ==

@SET /P COMPACTOS=Deploy as Compact OS? (Y or N):

@if %COMPACTOS%.==y. set COMPACTOS=Y

@echo Does this image include Extended Attributes?

@echo (If you're not sure, type N).

@SET /P EA=(Y or N):

@if %EA%.==y. set EA=Y

@if %COMPACTOS%.==Y. if %EA%.==Y. dism /Apply-Image /ImageFile:%1 /Index:1 /ApplyDir:W:\ /Compact /EA

@if not %COMPACTOS%.==Y. if %EA%.==Y. dism /Apply-Image /ImageFile:%1 /Index:1 /ApplyDir:W:\ /EA

@if %COMPACTOS%.==Y. if not %EA%.==Y. dism /Apply-Image /ImageFile:%1 /Index:1 /ApplyDir:W:\ /Compact

@if not %COMPACTOS%.==Y. if not %EA%.==Y. dism /Apply-Image /ImageFile:%1 /Index:1 /ApplyDir:W:\

@echo *********************************************************************

@echo == Copy boot files to the System partition ==

@echo == Note: specify /bootex parameter to use Windows UEFI 2023 CA

W:\Windows\System32\bcdboot W:\Windows /s S:

@echo *********************************************************************

@echo Next steps:

@echo * Add Windows Classic apps (optional):

@echo DISM /Apply-SiloedPackage /ImagePath:W:\

@echo /PackagePath:"D:\App1.spp" /PackagePath:"D:\App2.spp" ...

@echo.

@echo * Configure the recovery partition with ApplyRecovery.bat

@echo.

@echo * Reboot:

@echo exit

@GOTO END

:FFU

@echo Starting FFU Deployment

@echo list disk > x:\listdisks.txt

@echo exit >> x:\listdisks.txt

@diskpart /s x:\listdisks.txt

@del x:\listdisks.txt

@echo Enter the disk number of the drive where you're going to deploy your FFU (usually 0).

@SET /P DISKNUMBER=(Enter the Disk Number from above):

@echo This will remove all data from disk %DISKNUMBER%. Continue?

@SET /P ERASEALL=(Y or N):

@if %ERASEALL%.==y. set ERASEALL=Y

@if %ERASEALL%==Y DISM /apply-ffu /ImageFile=%1 /ApplyDrive:\\.\PhysicalDrive%DISKNUMBER%

@if not %ERASEALL%==Y GOTO END

@echo FFU applied. Would you like to configure the recovery partition?

@SET /P CONFIGRECOVERY=(Y or N):

@if %CONFIGRECOVERY%.==y. SET CONFIGRECOVERY=Y

@if %CONFIGRECOVERY%==Y ApplyRecovery.bat

@if not %CONFIGRECOVERY%==Y GOTO END

:END

ApplyImage.bat 依赖于以下 DiskPart 脚本，这些脚本必须放在同一文件夹中：

CreatePartitions 脚本

将这些脚本与 DiskPart 一起使用，可以为 Windows 格式化和设置硬盘分区，包括恢复工具。 必要时，请调整分区大小以便填充驱动器。

CreatePartitions-UEFI.txt

为基于 UEFI 的电脑创建系统、MSR、Windows 和恢复工具分区。

此脚本临时分配以下驱动器号：系统=S、Windows=W 和恢复=R。 MSR 分区不会获取驱动器号。 驱动器号 W 用于避免潜在的驱动器号冲突。 在设备重新启动后，系统会为 Windows 分区分配驱动器号 C，而其他分区不会获得驱动器号。

恢复分区必须是 Windows 分区之后的分区才能确保 winre.wim 在设备的生命周期内保持最新。

以下图表显示了最终的分区配置：

rem == CreatePartitions-UEFI.txt ==

rem == These commands are used with DiskPart to

rem create four partitions

rem for a UEFI/GPT-based PC.

rem Adjust the partition sizes to fill the drive

rem as necessary. ==

select disk 0

clean

convert gpt

rem == 1. System partition =========================

create partition efi size=200

rem ** NOTE: For Advanced Format 4Kn drives,

rem change this value to size = 300 **

format quick fs=fat32 label="System"

assign letter="S"

rem == 2. Microsoft Reserved (MSR) partition =======

create partition msr size=16

rem == 3. Windows partition ========================

rem == a. Create the Windows partition ==========

create partition primary

rem == b. Create space for the recovery tools ===

rem ** Update this size to match the size of

rem the recovery tools (winre.wim)

rem plus some free space.

shrink minimum=500

rem == c. Prepare the Windows partition =========

format quick fs=ntfs label="Windows"

assign letter="W"

rem === 4. Recovery partition ======================

create partition primary

format quick fs=ntfs label="Recovery"

assign letter="R"

set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"

gpt attributes=0x8000000000000001

list volume

exit

CreatePartitions-UEFI-FFU.txt

此脚本基于 CreatePartitions-UEFI.txt，但它不创建恢复分区。 这样，Windows 分区就是驱动器上的最后一个分区，并且可扩展。 如果使用此脚本，以后可以使用 ApplyRecovery.bat 来配置恢复分区。

rem == CreatePartitions-UEFI-FFU.txt ==

rem == These commands are used with DiskPart to

rem create four partitions

rem for a UEFI/GPT-based PC.

rem Adjust the partition sizes to fill the drive

rem as necessary. ==

select disk 0

clean

convert gpt

rem == 1. System partition =========================

create partition efi size=200

rem ** NOTE: For Advanced Format 4Kn drives,

rem change this value to size = 300 **

format quick fs=fat32 label="System"

assign letter="S"

rem == 2. Microsoft Reserved (MSR) partition =======

create partition msr size=16

rem == 3. Windows partition ========================

rem == a. Create the Windows partition ==========

create partition primary

rem == c. Prepare the Windows partition =========

format quick fs=ntfs label="Windows"

assign letter="W"

list volume

exit

CreatePartitions-BIOS.txt

为基于 BIOS 的电脑创建系统、Windows 和恢复工具分区。

此脚本临时分配以下驱动器号：系统=S、Windows=W 和恢复=R。 驱动器号 W 用于避免潜在的驱动器号冲突。 在设备重新启动后，系统会为 Windows 分区分配驱动器号 C，而其他分区不会获得驱动器号。

恢复分区必须是 Windows 分区之后的分区才能确保 winre.wim 在设备的生命周期内保持最新。

以下图表显示了最终的分区配置：

rem == CreatePartitions-BIOS.txt ==

rem == These commands are used with DiskPart to

rem create three partitions

rem for a BIOS/MBR-based computer.

rem Adjust the partition sizes to fill the drive

rem as necessary. ==

select disk 0

clean

rem == 1. System partition ======================

create partition primary size=100

format quick fs=ntfs label="System"

assign letter="S"

active

rem == 2. Windows partition =====================

rem == a. Create the Windows partition =======

create partition primary

rem == b. Create space for the recovery tools

rem ** Update this size to match the size of

rem the recovery tools (winre.wim)

rem plus some free space.

shrink minimum=500

rem == c. Prepare the Windows partition ======

format quick fs=ntfs label="Windows"

assign letter="W"

rem == 3. Recovery partition ====================

create partition primary

format quick fs=ntfs label="Recovery image"

assign letter="R"

set id=27

list volume

exit

CreatePartitions-BIOS-FFU.txt

此脚本基于 CreatePartitions-BIOS.txt，但它不创建恢复分区。 这样，Windows 分区就是驱动器上的最后一个分区，并且可扩展。 如果使用此脚本，以后可以使用 ApplyRecovery.bat 来配置恢复分区。

rem == CreatePartitions-BIOS-FFU.txt ==

rem == These commands are used with DiskPart to

rem create three partitions

rem for a BIOS/MBR-based computer.

rem Adjust the partition sizes to fill the drive

rem as necessary. ==

select disk 0

clean

rem == 1. System partition ======================

create partition primary size=100

format quick fs=ntfs label="System"

assign letter="S"

active

rem == 2. Windows partition =====================

rem == a. Create the Windows partition =======

create partition primary

rem == c. Prepare the Windows partition ======

format quick fs=ntfs label="Windows"

assign letter="W"

list volume

exit

ApplyRecovery.bat

使用此脚本准备 Windows 恢复分区。 此脚本由 ApplyImage.bat 调用，但也可以单独运行。

注意：如果复制并粘贴以下内容来创建 .bat 文件，则在检测固件时可能会出错。 要使固件检测成功，请确保以 for /f "tokens=2* delims= " %%A 开头的行包含一个制表符，并且该制表符后面的 delims= 与 " %%A 之间有一个空格。

@echo == ApplyRecovery.bat ==

@rem *********************************************************************

@echo Checking to see if the PC is booted in BIOS or UEFI mode.

wpeutil UpdateBootInfo

for /f "tokens=2* delims= " %%A in ('reg query HKLM\System\CurrentControlSet\Control /v PEFirmwareType') DO SET Firmware=%%B

@echo Note: delims is a TAB followed by a space.

@if x%Firmware%==x echo ERROR: Can't figure out which firmware we're on.

@if x%Firmware%==x echo Common fix: In the command above:

@if x%Firmware%==x echo for /f "tokens=2* delims= "

@if x%Firmware%==x echo ...replace the spaces with a TAB character followed by a space.

@if x%Firmware%==x goto END

@if %Firmware%==0x1 echo The PC is booted in BIOS mode.

@if %Firmware%==0x2 echo The PC is booted in UEFI mode.

@echo *********************************************************************

@echo Do you already have a recovery partition on this disk? (Y or N):

@SET /P RECOVERYEXIST=(Y or N):

@if %RECOVERYEXIST%.==y. set RECOVERYEXIST=Y

@if %RECOVERYEXIST%.==Y. GOTO COPYTOTOOLSPARTITION

@if not %RECOVERYEXIST%.==Y. GOTO CREATEFFURECOVERY

@echo *********************************************************************

:COPYTOTOOLSPARTITION

@echo == Copy the Windows RE image to the Windows RE Tools partition ==

md R:\Recovery\WindowsRE

xcopy /h W:\Windows\System32\Recovery\Winre.wim R:\Recovery\WindowsRE\

@echo *********************************************************************

@echo == Register the location of the recovery tools ==

W:\Windows\System32\Reagentc /Setreimage /Path R:\Recovery\WindowsRE /Target W:\Windows

@echo *********************************************************************

@IF EXIST W:\Recovery\Customizations\USMT.ppkg (GOTO CUSTOMDATAIMAGEWIM) else goto HIDEWIMRECOVERYTOOLS

:CUSTOMDATAIMAGEWIM

@echo == If Compact OS, single-instance the recovery provisioning package ==

@echo.

@echo *Note: this step only works if you created a ScanState package called

@echo USMT.ppkg as directed in the OEM Deployment lab. If you aren't

@echo following the steps in the lab, choose N.

@echo.

@echo Options: N: No

@echo Y: Yes

@echo D: Yes, but defer cleanup steps to first boot.

@echo Use this if the cleanup steps take more than 30 minutes.

@echo defer the cleanup steps to the first boot.

@SET /P COMPACTOS=Deploy as Compact OS? (Y, N, or D):

@if %COMPACTOS%.==y. set COMPACTOS=Y

@if %COMPACTOS%.==d. set COMPACTOS=D

@if %COMPACTOS%.==Y. dism /Apply-CustomDataImage /CustomDataImage:W:\Recovery\Customizations\USMT.ppkg /ImagePath:W:\ /SingleInstance

@if %COMPACTOS%.==D. dism /Apply-CustomDataImage /CustomDataImage:W:\Recovery\Customizations\USMT.ppkg /ImagePath:W:\ /SingleInstance /Defer

@echo *********************************************************************

:HIDEWIMRECOVERYTOOLS

@echo == Hiding the recovery tools partition

if %Firmware%==0x1 diskpart /s %~dp0HideRecoveryPartitions-BIOS.txt

if %Firmware%==0x2 diskpart /s %~dp0HideRecoveryPartitions-UEFI.txt

@echo *********************************************************************

@echo == Verify the configuration status of the images. ==

W:\Windows\System32\Reagentc /Info /Target W:\Windows

@echo (Note: Windows RE status may appear as Disabled, this is OK.)

@echo *********************************************************************

@echo All done!

@echo Disconnect the USB drive from the reference device.

@echo Type exit to reboot.

@echo.

GOTO END

:CREATEFFURECOVERY

@echo *********************************************************************

@echo == Creating the recovery tools partition

@if %Firmware%==0x1 diskpart /s CreateRecoveryPartitions-BIOS.txt

@if %Firmware%==0x2 diskpart /s CreateRecoveryPartitions-UEFI.txt

@echo finding the Windows Drive

@echo *********************************************************************

@IF EXIST C:\Windows SET windowsdrive=C:\

@IF EXIST D:\Windows SET windowsdrive=D:\

@IF EXIST E:\Windows SET windowsdrive=E:\

@IF EXIST W:\Windows SET windowsdrive=W:\

@echo The Windows drive is %windowsdrive%

md R:\Recovery\WindowsRE

@echo *********************************************************************

@echo Finding Winre.wim

@IF EXIST %windowsdrive%Recovery\WindowsRE\winre.wim SET recoveryfolder=%windowsdrive%Recovery\WindowsRE\

@IF EXIST %windowsdrive%Windows\System32\Recovery\winre.wim SET recoveryfolder=%windowsdrive%Windows\System32\Recovery\

@echo *********************************************************************

@echo copying Winre.wim

xcopy /h %recoveryfolder%Winre.wim R:\Recovery\WindowsRE\

@echo *********************************************************************

@echo == Register the location of the recovery tools ==

%windowsdrive%Windows\System32\Reagentc /Setreimage /Path R:\Recovery\WindowsRE /Target %windowsdrive%Windows

@echo *********************************************************************

@IF EXIST W:\Recovery\Customizations\USMT.ppkg (GOTO CUSTOMDATAIMAGEFFU) else goto HIDERECOVERYTOOLSFFU

:CUSTOMDATAIMAGEFFU

@echo == If Compact OS, single-instance the recovery provisioning package ==

@echo.

@echo *Note: this step only works if you created a ScanState package called

@echo USMT.ppkg as directed in the OEM Deployment lab. If you aren't

@echo following the steps in the lab, choose N.

@echo.

@echo Options: N: No

@echo Y: Yes

@echo D: Yes, but defer cleanup steps to first boot.

@echo Use this if the cleanup steps take more than 30 minutes.

@echo defer the cleanup steps to the first boot.

@SET /P COMPACTOS=Deploy as Compact OS? (Y, N, or D):

@if %COMPACTOS%.==y. set COMPACTOS=Y

@if %COMPACTOS%.==d. set COMPACTOS=D

@if %COMPACTOS%.==Y. dism /Apply-CustomDataImage /CustomDataImage:%windowsdrive%Recovery\Customizations\USMT.ppkg /ImagePath:%windowsdrive% /SingleInstance

@if %COMPACTOS%.==D. dism /Apply-CustomDataImage /CustomDataImage:%windowsdrive%Recovery\Customizations\USMT.ppkg /ImagePath:%windowsdrive% /SingleInstance /Defer

:HIDERECOVERYTOOLSFFU

@rem *********************************************************************

@echo == Hiding the recovery tools partition

@if %Firmware%==0x1 diskpart /s HideRecoveryPartitions-BIOS.txt

@if %Firmware%==0x2 diskpart /s HideRecoveryPartitions-UEFI.txt

@echo *********************************************************************

@echo == Verify the configuration status of the images. ==

%windowsdrive%Windows\System32\Reagentc /Info /Target %windowsdrive%Windows

@echo (Note: Windows RE status may appear as Disabled, this is OK.)

@echo *********************************************************************

@echo All done!

@echo Disconnect the USB drive from the reference device.

@echo Type exit to reboot.

@GOTO END

:END

ApplyRecovery.bat 依赖于以下 DiskPart 脚本，这些脚本必须放在同一文件夹中：

CreateRecoveryPartitions-UEFI.txt

rem == CreateRecoveryPartitions-UEFI.txt ==

rem == Find and label the Windows partition

rem ** This script assumes the partition layout from

rem CreatePartitions-UEFI or CreatePartitions-UEFI-FFU

select disk 0

select partition 3

assign letter="W"

rem == Extend the Windows partition

extend

rem == Create space for the recovery tools

rem ** Update this size to match the size of

rem the recovery tools (winre.wim)

rem plus some free space.

shrink minimum=500

rem == Create recovery partition

create partition primary

format quick fs=ntfs label="Recovery"

assign letter="R"

set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"

gpt attributes=0x8000000000000001

list volume

exit

CreateRecoveryPartitions-BIOS.txt

rem == CreateRecoveryPartitions-BIOS.txt ==

rem == Find and label the Windows partition

rem ** This script assumes the partition layout from

rem CreatePartitions-BIOS or CreatePartitions-BIOS-FFU

select disk 0

select partition 2

assign letter="W"

rem == Extend the Windows partition ==

shrink minimum=500

extend

rem == Create space for the recovery tools

rem ** Update this size to match the size of the

rem recovery tools (winre.wim), plus some free space.

shrink minimum=500

rem == Prepare the recovery partition ======

select disk 0

create partition primary

format quick fs=ntfs label="Recovery image"

assign letter="R"

set id=27

list volume

exit

HideRecoveryPartitions-UEFI.txt

rem === HideRecoveryPartitions-UEFI.txt ===

rem ** This script assumes the partition layout from

rem CreatePartitions-UEFI or CreatePartitions-UEFI-FFU

select disk 0

select partition 4

set id=de94bba4-06d1-4d40-a16a-bfd50179d6ac

gpt attributes=0x8000000000000001

remove

list volume

exit

HideRecoveryPartitions-BIOS.txt

rem === HideRecoveryPartitions-BIOS.txt ===

rem ** This script assumes the partition layout from

rem CreatePartitions-BIOS or CreatePartitions-BIOS-FFU

select disk 0

select partition 3

set id=27

remove

list volume

exit

BootToAudit

将应答文件添加到 Windows 映像中的 C:\mount\windows\Windows\Panther\unattend.xml，以指示映像启动进入审核模式。 你可以在 Windows 系统映像管理器中创建此应答文件。

BootToAudit-x64

Audit

通过恢复保留 Windows 设置

Windows 不会自动保存通过 unattend.xml 设置文件创建的设置，也不会自动保存全系统重置时使用 LayoutModification.xml 创建的 Windows “开始”菜单自定义以及来自 oobe.xml 的首次登录信息。

若要确保保存你的自定义，这包括以下步骤：将 unattend.xml、LayoutModification.xml 和 oobe.xml 文件放回原位。 下面是一些示例脚本，显示如何保留这些设置并将它们恢复到合适位置。 将 unattend.xml、LayoutModification.xml、oobe.xml 的副本以及 ResetConfig.xml 和 EnableCustomizations.cmd 这两个文本文件保存到 C:\Recovery\OEM\ 中：

ResetConfig.xml

EnableCustomizations.cmd

2

EnableCustomizations.cmd

2

EnableCustomizations.cmd

rem EnableCustomizations.cmd

rem Set the variable %TARGETOS% (Typically this is C:\Windows)

for /F "tokens=1,2,3 delims= " %%A in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\RecoveryEnvironment" /v TargetOS') DO SET TARGETOS=%%C

rem Set the variable %TARGETOSDRIVE% (Typically this is C:)

for /F "tokens=1 delims=\" %%A in ('Echo %TARGETOS%') DO SET TARGETOSDRIVE=%%A

rem Add back Windows settings, Start menu, and OOBE.xml customizations

copy "%TARGETOSDRIVE%\Recovery\OEM\Unattend.xml" "%TARGETOS%\Panther\Unattend.xml" /y

copy "%TARGETOSDRIVE%\Recovery\OEM\LayoutModification.xml" "%TARGETOSDRIVE%\Users\Default\AppData\Local\Microsoft\Windows\Shell\LayoutModification.xml" /y

xcopy "%TARGETOSDRIVE%\Recovery\OEM\OOBE\Info" "%TARGETOS%\System32\Info\" /s

rem Recommended: Create a pagefile for devices with 1GB or less of RAM.

wpeutil CreatePageFile /path=%TARGETOSDRIVE%\PageFile.sys /size=256

若要详细了解如何使用扩展点进行一键重置，请参阅将扩展性脚本添加到一键重置。

重新安装 Windows 内置应用

在添加新语言后重新安装 Windows 应用。 你无需首先删除应用即可重新安装这些应用。

ReinstallInboxApps-x64.cmd

ReinstallInboxApps-x64 是一个示例脚本，用于重新安装 Windows 随附的应用。 它只是一个示例，不一定会在系统上重新安装所有内置应用。 请确保使用自己的、包含设备上所有应用的脚本。

请注意，以下路径假定你已将收件箱应用 ISO 的内容复制到 C:\Temp\Lab\Apps\Inbox 文件夹。

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.CortanaApp_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.CortanaApp_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\Microsoft.UI.Xaml.x64.2.3.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.BingNews_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.BingNews_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\Microsoft.UI.Xaml.x64.2.3.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Advertising.Xaml.x64.10.0.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.BingWeather_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.BingWeather_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\Microsoft.UI.Xaml.x64.2.3.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Advertising.Xaml.x64.10.0.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.GamingApp_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.GamingApp_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.GetHelp_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.GetHelp_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Getstarted_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.Getstarted_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.HEIFImageExtension_8wekyb3d8bbwe.x64.appx /licensepath:.\Appx\Microsoft.HEIFImageExtension_8wekyb3d8bbwe.x64.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Messaging_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.Messaging_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.MicrosoftOfficeHub_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.MicrosoftOfficeHub_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.MicrosoftSolitaireCollection_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.MicrosoftSolitaireCollection_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Advertising.Xaml.x64.10.0.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Services.Store.Engagement.x64.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.MicrosoftStickyNotes_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.MicrosoftStickyNotes_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Paint_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.Paint_8wekyb3d8bbwe.xml

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.People_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.People_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Services.Store.Engagement.x64.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Advertising.Xaml.x64.10.0.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.ScreenSketch_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.ScreenSketch_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.SecHealthUI_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.SecHealthUI_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\Microsoft.UI.Xaml.x64.2.4.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.StorePurchaseApp_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.StorePurchaseApp_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Todos_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.Todos_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\Microsoft.UI.Xaml.x64.2.4.appx / dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VP9VideoExtensions_8wekyb3d8bbwe.x64.appx /licensepath:.\Appx\Microsoft.VP9VideoExtensions_8wekyb3d8bbwe.x64.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.WebMediaExtensions_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.WebMediaExtensions_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.WebpImageExtension_8wekyb3d8bbwe.x64.appx /licensepath:.\Appx\Microsoft.WebpImageExtension_8wekyb3d8bbwe.x64.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Windows.Photos_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.Windows.Photos_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.WindowsAlarms_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.WindowsAlarms_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.WindowsCalculator_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.WindowsCalculator_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.WindowsCamera_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.WindowsCamera_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.WindowsCommunicationsApps_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.WindowsCommunicationsApps_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Advertising.Xaml.x64.10.0.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.WindowsFeedbackHub_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.WindowsFeedbackHub_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.WindowsMaps_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.WindowsMaps_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.WindowsSoundRecorder_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.WindowsSoundRecorder_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.WindowsStore_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.WindowsStore_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.Xbox.TCUI_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.Xbox.TCUI_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.XboxIdentityProvider_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.XboxIdentityProvider_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Framework.x64.2.2.appx /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.NET.Native.Runtime.x64.2.2.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.XboxSpeechToTextOverlay_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.XboxSpeechToTextOverlay_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.XboxGameOverlay_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.XboxGameOverlay_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.YourPhone_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.YourPhone_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.ZuneMusic_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.ZuneMusic_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.ZuneVideo_8wekyb3d8bbwe.appxbundle /licensepath:.\Appx\Microsoft.ZuneVideo_8wekyb3d8bbwe.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

DISM /image:C:\Mount\Windows /add-ProvisionedAppxPackage /packagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\MicrosoftWindows.Client.WebExperience_cw5n1h2txyewy.appxbundle /licensepath:.\Appx\Microsoft.WebExperience_cw5n1h2txyewy.xml /dependencypackagepath:C:\Temp\Lab\Apps\Inbox\amd64fre\Microsoft.VCLibs.x64.14.00.appx

使用脚本查找驱动器号

在 Windows PE 中使用此脚本来识别包含“Images”文件夹的驱动器。

@echo Find a drive that has a folder titled Images.

@for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do @if exist %%a:\Images\ set IMAGESDRIVE=%%a

@echo The Images folder is on drive: %IMAGESDRIVE%

@dir %IMAGESDRIVE%:\Images /w